Option Explicit

Private CommandList As Collection

Private Sub Command1_Click()
    Inet1.URL = "ftp://vb-user.net/"
    Inet1.UserName = ユーザー名
    Inet1.Password = パスワード

    'ローカルの "C:\InetFTP.txt" を、FTPサーバーの
    'ftp://vb-user.net/www/junk/replySamples/2010.03.03.18.43/InetFTP.txt
    'に送出すると、このサーバーの場合は、Web サイトの
    'http://www.vb-user.net/junk/replySamples/2010.03.03.18.43/InetFTP.txt
    'のパスに保存されることになる。
    Set CommandList = New Collection
    CommandList.Add "CD /vb-user.net/www/junk/replySamples/2010.03.03.18.43"
    CommandList.Add "PUT C:\InetFTP.txt InetFTP.txt"
    CommandList.Add "QUIT"

    SendNextCommand
End Sub

Private Sub Inet1_StateChanged(ByVal State As Integer)
    Debug.Print State, Inet1.ResponseInfo
    If State = icError Then
        'エラー発生
        MsgBox Inet1.ResponseInfo, vbExclamation, Inet1.ResponseCode
    End If
    If State = icResponseCompleted Then
        'Debug.Print Inet1.GetChunk(1000)
        SendNextCommand
    End If
    If State = icDisconnected Then
        '切断されたので、残りのコマンドを破棄
        Do Until CommandList.Count = 0
            CommandList.Remove 1
        Loop
        SendNextCommand
    End If
End Sub

Private Sub SendNextCommand()
    If CommandList.Count = 0 Then
        MsgBox "処理完了", vbInformation
    Else
        Inet1.Execute , CommandList(1)
        CommandList.Remove 1
    End If
End Sub