'
'http://hpcgi1.nifty.com/MADIA/VBBBS/wwwlng.cgi?print+201205/12050003.txt
'
Option Strict On
Imports System.Windows.Forms
Imports System.Runtime.InteropServices

Public Class Form1
    Inherits Form

    <StructLayout(LayoutKind.Sequential, CharSet:=CharSet.Ansi)> _
    Private Class COPYDATASTRUCT
        Public dwData As IntPtr
        Public cbData As Integer
        <MarshalAs(UnmanagedType.LPStr)> Public lpData As String
        Public Sub New(ByVal text As String)
            dwData = IntPtr.Zero
            lpData = If(text, "")
            cbData = System.Text.Encoding.Default.GetByteCount(lpData)
        End Sub
    End Class

    Private Const WM_COPYDATA As Integer = &H4A

    Private Declare Unicode Function FindWindow Lib "user32" Alias "FindWindowW" _
        (ByVal lpClassName As String, _
         ByVal lpWindowName As String) As IntPtr

    Private Declare Ansi Function SendMessage Lib "user32" Alias "SendMessageA" _
        (ByVal hwnd As IntPtr, _
         ByVal msg As Integer, _
         ByVal wParam As IntPtr, _
         ByVal lParam As COPYDATASTRUCT) As Integer

    Private Sub Button1_Click(ByVal sender As Object, ByVal e As EventArgs) Handles Button1.Click
        Dim hWndTo As IntPtr = FindWindow(Nothing, "TargetForm1")
        If IntPtr.Zero.Equals(hWndTo) Then
            Return
        End If

        Dim data As New COPYDATASTRUCT(TextBox1.Text)
        Dim lresult As Integer = SendMessage(hWndTo, WM_COPYDATA, IntPtr.Zero, data)
        If lresult <> 0 Then
            Throw New System.ComponentModel.Win32Exception(lresult)
        End If
    End Sub
End Class